<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">package Text::Wrap;

require Exporter;

@ISA = qw(Exporter);
@EXPORT = qw(wrap fill);
@EXPORT_OK = qw($columns $break $huge);

$VERSION = 2001.0131;

use vars qw($VERSION $columns $debug $break $huge);
use strict;

BEGIN	{
	$columns = 76;  # &lt;= screen width
	$debug = 0;
	$break = '\s';
	$huge = 'wrap'; # alternatively: 'die' or 'overflow'
}

use Text::Tabs qw(expand unexpand);

sub wrap
{
	my ($ip, $xp, @t) = @_;

	my $r = "";
	my $tail = pop(@t);
	my $t = expand(join("", (map { /\s+\Z/ ? ( $_ ) : ($_, ' ') } @t), $tail));
	my $lead = $ip;
	my $ll = $columns - length(expand($ip)) - 1;
	my $nll = $columns - length(expand($xp)) - 1;
	my $nl = "";
	my $remainder = "";

	pos($t) = 0;
	while ($t !~ /\G\s*\Z/gc) {
		if ($t =~ /\G([^\n]{0,$ll})($break|\Z(?!\n))/xmgc) {
			$r .= unexpand($nl . $lead . $1);
			$remainder = $2;
		} elsif ($huge eq 'wrap' &amp;&amp; $t =~ /\G([^\n]{$ll})/gc) {
			$r .= unexpand($nl . $lead . $1);
			$remainder = "\n";
		} elsif ($huge eq 'overflow' &amp;&amp; $t =~ /\G([^\n]*?)($break|\Z(?!\n))/xmgc) {
			$r .= unexpand($nl . $lead . $1);
			$remainder = $2;
		} elsif ($huge eq 'die') {
			die "couldn't wrap '$t'";
		} else {
			die "This shouldn't happen";
		}
			
		$lead = $xp;
		$ll = $nll;
		$nl = "\n";
	}
	$r .= $remainder;

	print "-----------$r---------\n" if $debug;

	print "Finish up with '$lead'\n" if $debug;

	$r .= $lead . substr($t, pos($t), length($t)-pos($t))
		if pos($t) ne length($t);

	print "-----------$r---------\n" if $debug;;

	return $r;
}

sub fill 
{
	my ($ip, $xp, @raw) = @_;
	my @para;
	my $pp;

	for $pp (split(/\n\s+/, join("\n",@raw))) {
		$pp =~ s/\s+/ /g;
		my $x = wrap($ip, $xp, $pp);
		push(@para, $x);
	}

	# if paragraph_indent is the same as line_indent, 
	# separate paragraphs with blank lines

	my $ps = ($ip eq $xp) ? "\n\n" : "\n";
	return join ($ps, @para);
}

1;
__END__

=head1 NAME

Text::Wrap - line wrapping to form simple paragraphs

=head1 SYNOPSIS 

B&lt;Example 1&gt;

	use Text::Wrap

	$initial_tab = "\t";	# Tab before first line
	$subsequent_tab = "";	# All other lines flush left

	print wrap($initial_tab, $subsequent_tab, @text);
	print fill($initial_tab, $subsequent_tab, @text);

	@lines = wrap($initial_tab, $subsequent_tab, @text);

	@paragraphs = fill($initial_tab, $subsequent_tab, @text);

B&lt;Example 2&gt;

	use Text::Wrap qw(wrap $columns $huge);

	$columns = 132;		# Wrap at 132 characters
	$huge = 'die';
	$huge = 'wrap';
	$huge = 'overflow';

B&lt;Example 3&gt;
	
	use Text::Wrap

	$Text::Wrap::columns = 72;
	print wrap('', '', @text);

=head1 DESCRIPTION

Text::Wrap::wrap() is a very simple paragraph formatter.  It formats a
single paragraph at a time by breaking lines at word boundries.
Indentation is controlled for the first line (C&lt;$initial_tab&gt;) and
all subsquent lines (C&lt;$subsequent_tab&gt;) independently.  Please note: 
C&lt;$initial_tab&gt; and C&lt;$subsequent_tab&gt; are the literal strings that will
be used: it is unlikley you would want to pass in a number.

Lines are wrapped at C&lt;$Text::Wrap::columns&gt; columns.  C&lt;$Text::Wrap::columns&gt;
should be set to the full width of your output device.  In fact,
every resulting line will have length of no more than C&lt;$columns - 1&gt;.  

Beginner note: In example 2, above C&lt;$columns&gt; is imported into
the local namespace, and set locally.  In example 3,
C&lt;$Text::Wrap::columns&gt; is set in its own namespace without importing it.

When words that are longer than C&lt;$columns&gt; are encountered, they
are broken up.  C&lt;wrap()&gt; adds a C&lt;"\n"&gt; at column C&lt;$columns&gt;.
This behavior can be overridden by setting C&lt;$huge&gt; to
'die' or to 'overflow'.  When set to 'die', large words will cause
C&lt;die()&gt; to be called.  When set to 'overflow', large words will be
left intact.  

Text::Wrap::fill() is a simple multi-paragraph formatter.  It formats
each paragraph separately and then joins them together when it's done.  It
will destory any whitespace in the original text.  It breaks text into
paragraphs by looking for whitespace after a newline.  In other respects
it acts like wrap().

When called in list context, C&lt;wrap()&gt; will return a list of lines and 
C&lt;fill()&gt; will return a list of paragraphs.

Historical notes: Older versions of C&lt;wrap()&gt; and C&lt;fill()&gt; always 
returned strings.  Also, 'die' used to be the default value of
C&lt;$huge&gt;.  Now, 'wrap' is the default value.

=head1 EXAMPLE

	print wrap("\t","","This is a bit of text that forms 
		a normal book-style paragraph");

=head1 AUTHOR

David Muir Sharnoff &lt;muir@idiom.com&gt; with help from Tim Pierce and
many many others.  

</pre></body></html>